Учебно-методический комплекс по дисциплине “Моделирование процессов бурения ” (стр. 25 )

Интервал нагрузок от до подбирается так, чтобы охватить все три зоны:

В первой зоне разрушение из-за недостаточной нагрузки идет неэффективно; рост нагрузки слабо влияет на рост скорости. Скорость низка и линия зависимости – полога.

Во второй зоне разрушение эффективно, линия зависимости круто поднимается.

В третьей зоне образующееся при бурении с очень высокой нагрузкой количество шлама настолько велико, что промывка не в состоянии его полностью удалять. Подачи насоса недостаточно. Идет накопление шлама, и скорость бурения почти не растет. Намечается тенденция к ее падению.

Вид зависимости скорости от нагрузки, представленный на рис 15.2, характерен только для средних пород. В очень крепких (таких как роговики) породах реально невозможно создать нагрузку вне зоны поверхностного разрушения; в мягких же породах (пески) практически любая осевая нагрузка может привести к режиму зашламования.

Кривая на рис.15.2 имеет в середине точку перегиба, левее которой темп нарастания скорости с нагрузкой возрастает, а правее убывает. Здесь соединяются две квадратичные параболы: возрастающая (вогнутая), и убывающая (выпуклая). Если учесть, что на построение каждой из парабол требуется по три опытных точки, то всего это даст = 6 опытных точки. Согласно формуле (15.3) проходящее через эти точки уравнение будет иметь максимальную степень =5. Это уравнение (15.2), где вместо знаков Х стоят обозначения осевой нагрузки С:

(15.4)

С помощью этого уравнения для любого значения осевой нагрузки можно найти соответствующую скорость бурения. Но это можно сделать, только установив значения коэффициентов от до . Чтобы найти 6 неизвестных коэффициентов, необходимо составить систему из 6 линейных уравнений. Это можно сделать на основании результатов опытов, проведенных в 6 опытных точках:

…………………………………………………

, (15.5)

где средняя скорость бурения для каждого значения осевой нагрузки , а J – номер опыта, меняющийся от 1 до 6. Значения всех и нам известны. Подставив скорости, и нагрузки во всех требующихся степенях и решив систему методом, описанным в предшествующей лекции, мы решим поставленную проблему

Компьютерная модель зависимости

Программа VfnC (V в функции от C)

10 CLS

20 PRINT “ЗАВИСИМОСТЬ СКОРОСТИ ОТ ОСЕВОЙ НАГРУЗКИ”

30 DIM V(20,10), VSR(20), C(20), A(30,30)

40 DATA 0.2,0.4,0.5, 1.2,1.4,1.4, 4.8,5.3,6.4, 9.6,10.1,11.1, 13.2,14.2,14.8, 14.9,15.1,15.7

50 CMIN=0.3: CMAX=1.8

60 N=5: L=3: NI=N+2: NJ=N+1

70 H=(CMAX-CMIN)/N

80 FOR J=1 TO NJ

90 C(J)=CMIN+H*(J-1)

100 T=10+J*6

110 LOCATE 2,2: PRINT “J”

120 LOCATE 3,2: PRINT “C”

130 LOCATE 4,2: PRINT “VSR”

140 LOCATE 2,T: PRINT USING “###”; J

150 LOCATE 3,T: PRINT USING “##.##”; C(J)

160 NEXT J

170 FOR J=1 TO NJ

180 VSR(J) = 0

190 FOR I=1 TO L

200 READ V(J, I)

210 VSR(J)=VSR(J)+V(J, I)

220 NEXT I

230 VSR(J)=VSR(J)/L

240 T=10+J*6

250 LOCATE 4,T: PRINT USING “###.##”; VSR(J)

260 A(J,1)=1

270 A(J, NI)= –VSR(J)

280 NEXT J

290 FOR J=1 TO NJ

300 FOR I=2 TO NI-1

310 A(J, I)=C(J)^(I-1)

320 NEXT I

330 NEXT J

340 GOSUB 810

350 CLS

360 M = 1

370 FOR J = 1 TO NJ

380 S = A(J, M)

390 FOR I = M TO NI

400 A(J, I) = A(J, I)/S

410 NEXT I

420 NEXT J

430 GOSUB 810

440CLS

450 FOR I = M TO NI

460 B(M, I) = A(1,I)

470 NEXT I

480 FOR J = 2 TO NJ

490 FOR I = M TO NI

500 A(J-1,I) = B(M, I)-A(J, I)

510 NEXT I

520 NEXT J

530 GOSUB 810

540 CLS

550 M = M+1

560 NJ = NJ–1

570 IF M > NI–1 THEN 590

580 GOTO 370

590 FOR K=1 TO NI–1

600 M = NI–K

610 C(K) = 0

620 FOR I = M TO NI–1

630 P(M, I) = B(M, I+1)*X(I+1)

640 C(K) = C(K)+P(M, I)

650 NEXT I

660 X(M) = – (B(M, NI)+C(K))

670 NEXT K

680 CLS

690 LOCATE 2,2: PRINT “V=”

700 FOR K=1 TO NI-1

710 K3= 4+(K–1)*12

720 LOCATE 2,K3: PRINT USING “###.###”;X(K)

730 K4=11+(K–1)*12

740 LOCATE 2,K4: PRINT “C^”

750 K5=13+(K–1)*12

760 LOCATE 2,K5: PRINT USING “#”;K-1

770 K6=14+(K–1)*12

780 LOCATE 2,K6: PRINT “+”

790 NEXT K

800 GOTO 900

810 FOR J=1 TO NJ

820 K1=7+2*J

830 FOR I=1 TO NI

840 K2=4+9*I

850 LOCATE K1,K2: PRINT USING “######.##”; A(J, I)

860 NEXT I

870 NEXT J

880 INPUT A$

890 RETURN

900 END

После заголовка программы и оператора CLS в номере 30 задаются размерности двухмерных и одномерных индексных переменных. В операторе 40 DATA дается перечень значений скоростей бурения , полученных в ходе эксперимента (по 3 скорости для каждого значения нагрузки). В строке 50 CMIN = 0.3: CMAX = 1.8 задаются минимальные и максимальные нагрузки, использованные в эксперименте

Далее идет строка 60 N = 5: L = 3: NI = N + 2: NJ = N + 1. В ней задается число делений N, на которые разбивается интервал от до . Это число на 1 меньше числа опытных точек. В примере, задуман эксперимент с 6 испытываемыми зн ачениями нагрузки, поэтому число делений равно N = 5. Составляется NJ =6 уравнений, а каждое уравнение (вместе со свободным членом ) содержит NI = 7 членов. При каждом значении осевой нагрузки проводится L = 3 опыта. В строке 70 вычисляется длина деления интервала от до (h = 0.3 т).

В строках 80 – 160 располагается цикл по параметру J. Внутри цикла в операторе 90 C(J) = CMIN+H*(J-1) фиксируются использованные в опыте значения осевой нагрузки с изменением J от 1 до NJ (до 6). Так, = (0.3 т), = 0.3+0.3*(2–1)= 0.6 т и т. д. до = 0.3+0.3*(6-1) = 1.8 т (т. е. до )

В операторах 100 – 150 значения нагрузки и соответствующие значения J выведены на печать в виде таблицы. Слева таблица имеет “боковик”, содержащий названия строк J и C. Так, оператор 110 LOCATE 2,2: PRINT “J” определяет, что буква J должна быть расположена на второй сверху строке экрана и на второй позиции от его левого края. Буква С (номер 120) располагается тоже на 2-й позиции, но одной строкой ниже (строка 3). Шесть же значений нагрузки, (найденные согласно оператору 90) печатаются на той же строке 3 друг после друга с интервалами, определяемыми параметром 100 T=10+J*6 (с интервалами в 6 позиций, начиная с 10-й). Так печатается с 10-й по 16-ю позиции, – с 16-й по 22-ю и т. д. (см таблицу 15.1). Аналогичным образом, но на строке 2 печатаются значения J.

В операторах 170 – 280 по частным значениям скоростей (j – номер опыта, а i – номер повторения j-го опыта), рассчитываются средние скорости : После заголовка внешнего цикла (170) в строке 180 VSR = 0 производится обнуление с целью последующего суммирования. Далее идет заголовок внутреннего цикла: 190 FOR I = 1 TO L. В операторе 200 READ V(J, I) производится ввод записанных в операторе DATA. значений скоростей. В номере 210 VSR(J) = VSR(J)+V(J, I) производится суммирование L значений скоростей для каждого j-го значения осевой нагрузки. По окончании внутреннего цикла в строке 230 полученная сумма VSR(J) делится на число повторений опыта и таким образом вычисляется средняя скорость , – в программе она названа VSR(J).

В строках 240 – 250 значения VSR(J) заносятся в таблицу вывода ниже значений нагрузки. (В операторе 250 LOCATE 4,T: PRINT USING “###.#”; VSR(J), указано, что запись средних скоростей производится на 4- й сверху строке экрана). Обозначение же этой строки подготовлено выше: 130 LOCATE 4,2: PRINT “VSR”